Syntax for agent-based flexible management policies

You can use the syntax described in the following sections as a basis for configuring agent-based flexible management features.

Special Characters in agent-based Flexible Management Templates:

The syntax examples below use the following special characters:

Symbol	Description
e	Empty string. Note that "e" is used only in the examples. In the actual template, an empty string should, in fact, be used.
#	Comment. If you want to include a comment in a template, include a number sign (#) before every line of the comment. Every character in the line is treated as part of the comment. Example: # This is a comment
\	Escape character. If you want to use quotation marks in a syntax string, escape the quotation marks with a backslash (\). Example: \"quotation\"

Syntax for Responsible Management Server Configuration policies

Use the following syntax for responsible management server configuration policies:

respmgrconfigs ::= <respmgrconfigs> RESPMGRCONFIG DESCRIPTION  <string> <respmgrconds> | e

respmgrconds   ::= SECONDARYMANAGERS <secondmgrs> ACTIONALLOWMANAGERS <actallowmgrs>  
				 [MSGTARGETRULES <msgtargetrules>]

secondmgrs	 ::= <secondmgrs> SECONDARYMANAGER NODE <node>  [DESCRIPTION <string>] | e

actallowmgrs   ::= <actallowmgrs> ACTIONALLOWMANGER NODE <node> [DESCRIPTION <string>] | e

msgtargetrules ::= <msgtargetrules> MSGTARGETRULE DESCRIPTION <string> <msgtargetrule> | e

msgtargetrule  ::= MSGTARGETRULECONDS <mtrconditions> MSGTARGETMANAGERS <msgtargetmgrs>
				 | MSGTARGETRULECONDS <mtrconditions> MSGTARGETMANAGERS <msgtargetmgrs> ACKNONLOCALMGR

mtrconditions  ::= <mtrconditions> MSGTARGETRULECOND DESCRIPTION <string> <mtrcond> | e

mtrcond		::= <mtrcond> SEVERITY <severity> |
				 <mtrcond> NODE <nodelist> |
				 <mtrcond> APPLICATION <string> |
				 <mtrcond> MSGGRP <string> |
				 <mtrcond> OBJECT <string> |
				 <mtrcond> MSGTYPE <string> | 
				 <mtrcond> TEXT <string> |
				 <mtrcond> SERVICE_NAME <string> |
				 <mtrcond> MSGCONDTYPE <msgcondtype> | e

severity	::= Unknown | Normal | Warning | Critical | 

				Minor | Major

msgcondtype   ::= Match | Suppress

nodelist	::= <node> | <nodelist> <node> 

node		::= IP <ipaddress> | IP <ipaddress> <string>

string		::= "any alphanumeric string"

ipaddress	 ::= <digits>.<digits>.<digits>.<digits>

Syntax for Time Templates

Use the following syntax for time templates:

timetmpls	 ::= <timetmpls> TIMETEMPLATE <string> 

				DESCRIPTION 

				<string> <conditions> | e

conditions	::= TIMETMPLCONDS <timetmplconds> | e

timetmplconds ::= <timetmplconds> TIMETMPLCOND <timetmplcond>

timetmplcond  ::= [TIMECONDTYPE <timecondtype>] [TIME FROM 

				<time> TO <time>] [WEEKDAY <weekday>] 

				[DATE <exact_date>] | e

timecondtype  ::= Match | Suppress

time		::= <hh>:<mm>

weekday	 ::= ON <day> | FROM <day> TO <day>

exact_date	::= ON <date> | FROM <date> TO <date>

day		 ::= Monday | Tuesday | Wednesday | Thursday 

				 | Friday | Saturday | Sunday

date		::= <mm>/<dd>/<yyyy> |<mm>/<dd>/*

NOTE:
The time template is compared with the creation time of the message on the managed node. Message creation time is always defined in GMT.

Syntax for Management Responsibility Switching

Use the following syntax for templates that switch management server responsibility:

configfile := [TIMETEMPLATES <timetmpls>] RESPMGRCONFIGS 

			<respmgrconfigs>

Syntax for Message Target Rules

Use the following syntax for templates that define message target rules:

msgtargetmgrs ::= <msgtargetmgrs> MSGTARGETMANAGER 

				TIMETEMPLATE <string> OPCMGR <node> | 

				<msgtargetmgrs> MSGTARGETMANAGER 

				TIMETEMPLATE <string> OPCMGR <node> 

				MSGCONTROLLINGMGR | <msgtargetmgrs> 

				MSGTARGETMANAGER TIMETEMPLATE <string> 

				OPCMGR <node> NOTIFYMGR | e

NOTE:
You can replace the <string> variable with $OPC_ALWAYS to specify that the time condition is always true. To specify that the current primary management server is always used as the message target server, replace the <node> variable with $OPC_PRIMARY_MGR. Note also that pattern matching is only available in <string>.