Syntax of server-based flexible management policies


A management server compares every incoming message to the server-based flexible management policy. If the message attributes match the rules, the management server forwards the message to the other management servers specified in the policy. A policy is designed according to syntax rules. The flexible management policy syntax is in EBNF (Extended Backus-Naur Form). The server-based flexible management policy editor enables you to check that a policy has valid syntax.
Note NOTE:
Management servers evaluate only the first matching MESSAGETARGETRULE in the policy. For example, you have a message target rule A with the condition to match on critical messages and the rule to forward these kinds of messages to server X. You have another message target rule B, with the condition to match on messages with application "test" and the rule to forward these kinds of messages to server Y.

If a critical message arrives with application "test," then this message matches rules A and B, but the management server evaluates only the first matching rule and so forwards the message only to server X and not to server Y.

If you do not want this behavior, you must write an additional message target rule that matches only on critical messages with application "test" and forward these messages to server X and server Y; then you must place this rule before rule A.

Note NOTE:
HPOM for UNIX allows time templates but HPOM for Windows does not. The syntax below does not contain time templates, although you will find them in the HPOM for UNIX example files.

EBNF notation

<configfile>
				::= <epsilon>
				| RESPMGRCONFIGS <respmgrconfigs>
<respmgrconfigs>
				::= <epsilon>
					 | <respmgrconfigs> RESPMGRCONFIG DESCRIPTION <string> <respmgrconds>
<respmgrconds>
				::= SECONDARYMANAGERS <secondmgrs> ACTIONALLOWMANAGERS <actallowmgrs>
				| SECONDARYMANAGERS <secondmgrs> ACTIONALLOWMANAGERS <actallowmgrs> MSGTARGETRULES <msgtargetrules>
				| MSGTARGETRULES <msgtargetrules>
<secondmgrs> 
				::= <epsilon>
				| <secondmgrs> SECONDARYMANAGER NODE <node>
				| <secondmgrs> SECONDARYMANAGER NODE <node> DESCRIPTION <string> 
<actallowmgrs> 
				::= <epsilon>
				| <actallowmgrs> ACTIONALLOWMANAGER NODE <node>
				| <actallowmgrs> ACTIONALLOWMANAGER NODE <node> DESCRIPTION <string>
<msgtargetrules>
				::= <epsilon>
				| <msgtargetrules> MSGTARGETRULE DESCRIPTION <string> <msgtargetrule>
<msgtargetrule>
				::= MSGTARGETRULECONDS <mtrconditions> MSGTARGETMANAGERS <msgtargetmgrs>
				| MSGTARGETRULECONDS <mtrconditions> MSGTARGETMANAGERS <msgtargetmgrs>  
<mtrconditions> 
				::= <epsilon>
				| <mtrconditions> MSGTARGETRULECOND DESCRIPTION <string> <mtrcond>
<mtrcond>
				::= <epsilon>
				| <mtrcond> SEVERITY <severity>
				| <mtrcond> NODE <nodelist>
				| <mtrcond> APPLICATION  <string>
				| <mtrcond> MSGGRP <string>
				| <mtrcond> OBJECT <string>
				| <mtrcond> MSGTYPE <string>
				| <mtrcond> TEXT <string>
				| <mtrcond> SERVICE_NAME <string>
				| <mtrcond> MSGCONDTYPE <msgcondtype>
<msgtargetmgrs>
				::= <epsilon>
				| <msgtargetmgrs> MSGTARGETMANAGER TIMETEMPLATE "$OPC_ALWAYS" OPCMGR <node> 
<severity>
				::= Unknown | Normal | Warning | Minor | Mayor | Critical
<msgcondtype>
				::= Match | Suppress
<nodelist>
				::= <node>
				| <nodelist> <node>
<node> 
				::= IP <ipaddress>
				| IP <ipaddress> <string>
<string>
				::= "any alphanumeric string"
<ipaddress>
				::= <digits>.<digits>.<digits>.<digits>
Note NOTE:
For detailed descriptions of the attributes used in the syntax described here, see the help topic Keywords for flexible management policies.

Note NOTE:
The keywords ACKNONLOCALMGR, MSGCONTROLLINGMGR, and NOTIFYMGR are not supported for server-based flexible management policies.

Note note:
The syntax check allows the keywords SECONDARYMANAGERS and ACTIONALLOWMANAGERS in server-based flexible management policies for backwards compatibility with MsgForwarding.ini files. However, these keywords have no effect in server-based flexible management policies.